10 DATA"CONTENTS","INTRODUCTION","GETTING STARTED","TERM/AUTODIAL"
20 DATA"SCRIPT FILES","EXTERNAL PROGS","PARAMETERS LEFT","PARAMETERS RIGHT"
30 DATA"DISK/BUFFER/XFER","MEMORY MAP"
40 POKE45,PEEK(174):POKE46,PEEK(175):POKE49152,0:CLR:DIMF$(9),M%(9),N%(9)
50 IFPEEK(38400)<>76THENPRINT"[205]UST LOAD [206]OVATERM FIRST":END
60 FORI=0TO9:READF$(I):NEXT:ML=38400:SL=52608:DV=PEEK(186):IFDV<8ORDV>16THENDV=8
70 P$="[206]OVATERM 9.5 DOCUMENTATION                                    [208]AGE"
80 U$="[163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163]"
90 OPEN15,DV,15:PRINT"[147][201]NSERT DOCUMENTATION DISK IN DEVICE"DV:PRINT"AND HIT RETURN"
100 GETA$:IFA$<>CHR$(13)THEN100
110 PRINT"[195]HECKING FOR ALL FILES..."
120 OPEN1,DV,0,"$":GET#1,A$,A$:SYSML+54
130 SYSML+54:IFRIGHT$(Z$,1)="."ORRIGHT$(Z$,4)="FREE"THENCLOSE1:GOTO180
140 F$="":FORI=7TO22:IFMID$(Z$,I,1)=CHR$(34)THENI=22:GOTO160
150 F$=F$+MID$(Z$,I,1)
160 NEXT:FORI=0TO9:IFF$=F$(I)THENM%(I)=1:I=8
170 NEXT:GOTO130
180 J=0:FORI=0TO8:IFM%(I)=0THENPRINT"[206]OT ALL DOCUMENTATION FILES FOUND!":GOTO630
190 PRINT"[197]NTER LINES PER PAGE:":PRINT"(DEFAULT = 60)":PRINT"[145][145]"TAB(22);
200 GOSUB710:PG=VAL(I$):IFPG=0THENPG=60
210 PRINT"[197]NTER PHYSICAL PAGE SIZE:":PRINT"(DEFAULT = 66)":PRINT"[145][145]"TAB(26);
220 GOSUB710:PH=VAL(I$):IFPH=0THENPH=66
230 PRINT"[197]NTER SECONDARY ADDRESS:":PRINT"(DEFAULT = 7)":PRINT"[145][145]"TAB(25);
240 GOSUB710:PS=VAL(I$):IFPS=0THENPS=7
250 PRINT"[208]RINT [193][146]LL OR [211][146]OME DOC FILES?  [146][157]";
260 GETA$:IFA$<>"A"ANDA$<>"S"THEN260
270 PRINTCHR$(ASC(A$)+128):IFA$="A"THENN%(0)=0:FORI=1TO8:N%(I)=1:NEXT:GOTO300
280 PRINT:FORI=0TO8:PRINT"[208]RINT "F$(I)"?  [146][157]";:GOSUB720:N%(I)=Y:NEXT
290 PRINT"[211]TART FROM WHAT PAGE NUMBER: ";:GOSUB710:P=VAL(I$):IFP=0THENP=1
300 PRINT"[193]LIGN PRINTER PAPER AND HIT RETURN"
310 GETA$:IFA$<>CHR$(13)THEN310
320 PRINT"[208]RESS  [211] [146] TO STOP OR  [208] [146] TO PAUSE":PRINT"DURING PRINTING"
330 OPEN4,4,PS
340 IFN%(0)=0THENPRINT"[208]RINT TABLE OF CONTENTS?  [146][157]";:GOSUB720:IFY=0THEN420
350 OPEN2,DV,2,F$(0):INPUT#15,E:IFE>19THEN420
360 PRINT:PRINT"[208]RINTING "F$(0);:L=0
370 POKE781,2:SYSML+60:F=ST:PRINT#4,"        "S$;:L=L+1
380 IFL=PGTHENFORI=PG+1TOPH:PRINT#4:NEXT:L=0
390 GETA$:IFA$="P"THENWAIT198,1:GETA$
400 IFF=0ANDA$<>"S"THEN370
410 FORI=L+1TOPH:PRINT#4:NEXT:IFA$="S"THEN500
420 CLOSE2:L=0:P=1:FORK=1TO8:IFM%(K)=0ORN%(K)=0THEN510
430 OPEN2,DV,2,F$(K):INPUT#15,E:IFE>19THEN510
440 PRINT:PRINT"[208]RINTING "F$(K);
450 POKE781,2:SYSML+60:F=ST:PRINT#4,"     "S$;:L=L+1
460 IFL=PGTHENGOSUB690
470 GETA$:IFA$="P"THENWAIT198,1:GETA$
480 IFA$="S"THENK=8:F=1
490 IFF=0THEN450
500 CLOSE2:IFL>3THENGOSUB690
510 NEXT:IFM%(9)=0THEN620
520 PRINT"[208]RINT MEMORY MAP?  [146][157]";:GOSUB720:IFY=0THEN620
530 P$="[206]OVATERM 9.5 MEMORY MAP                                       [208]AGE":P=1
540 OPEN2,DV,2,F$(9):INPUT#15,E:IFE>19THEN610
550 PRINT:PRINT"[208]RINTING "F$(9);
560 POKE781,2:SYSML+60:F=ST:PRINT#4,"     "S$;:L=L+1
570 IFL=PGTHENGOSUB690
580 GETA$:IFA$="P"THENWAIT198,1:GETA$
590 IFA$="S"THENI=8:F=1
600 IFF=0THEN560
610 CLOSE2
620 PRINT:PRINT"[196]ONE - [212]RY AGAIN?  [146][157]";:GOSUB720:IFYTHEN300
630 PRINT"[201]NSERT [206]OVATERM DISK AND HIT RETURN"
640 GETA$:IFA$<>CHR$(13)THEN640
650 OPEN2,DV,0,"PROG MENU":INPUT#15,E:CLOSE2:IFE>19THEN670
660 LOAD"PROG MENU",DV
670 OPEN2,DV,0,"NOVATERM ?.?*":INPUT#15,E:CLOSE2:IFE>19THENEND
680 PRINT"[147]":LOAD"NOVATERM ?.?*",DV
690 FORI=L+1TOPH:PRINT#4:NEXT:P=P+1:PRINT#4,"     "P$P:PRINT#4,"     "U$:PRINT#4
700 L=3:RETURN
710 OPEN9,3:POKE780,3:SYSML+39:CLOSE9:RETURN
720 GETA$:IFA$<>"Y"ANDA$<>"N"THEN720
730 IFA$="N"THENPRINT"NO":Y=0:RETURN
740 PRINT"YES":Y=1:RETURN